Salesforce CPQ – Pull Quote Line Groups into Renewals and Amendments

Hello! If you’re here, you’re looking for how to pull groups into your amendments and/or renewals! You might have come from the Salesforce Idea page or perhaps google search….

There is a checkbox field, a trigger and a Price Rule involved. Fear not! All of it is right here.

Please NOTE: This code is provided as is. It might not work in your org. Creating these things requires a system administrator profile and access to all objects/fields involved. The trigger code may fail based on your org’s validation rules or other automation. It also might cause an APEX timeout because of this processing time + existing automation processing time. The price rule may fail because of other automation or price/product rules/validations you have in place. So, put these things in place, test it out, modify where necessary to fit your org.

Please NOTE: The Custom Checkbox field and Price Rule are to get around a “Legacy Renewal Service” issue. If you have the Legacy Renewal Service turned on, CPQ will not let the trigger set the Group Line Items field on the Quote object. So we set a custom version of this field (Has_Groups__c) to TRUE and then the Price Rule conditions on this custom field and checks the Group Line Items CPQ field on the Quote. If this Price Rule does not run, you will get a forever spinning “waiting” dots image because of a javascript error. Essentially, there are groups on the quote but the line editor doesn’t think there is because the checkbox is unchecked so it kabooms and waits forever.

Checkbox Field
Quote -> Has Groups (Has_Groups__c)

Quote Trigger Helper Class
Name: QuoteTriggerHelper

public class QuoteTriggerHelper {
    public static boolean insertMissingAmendmentRenewalLineGroupsRun = false;
    public static void runTriggers(Map<Id, SBQQ__Quote__c> newQuotesMap) {
        if (Trigger.isAfter) {
            if (Trigger.isUpdate) {
                QuoteTriggerHelper.doInsertMissingAmendmentRenewalLineGroups(newQuotesMap);
            }
        }
    }
    
    public static void doInsertMissingAmendmentRenewalLineGroups(Map<Id, SBQQ__Quote__c> newQuotesMap) {
        if (!QuoteTriggerHelper.insertMissingAmendmentRenewalLineGroupsRun) {
            QuoteTriggerHelper.insertMissingAmendmentRenewalLineGroupsRun = true;
            QuoteTriggerHelper.insertMissingAmendmentRenewalLineGroups(newQuotesMap, null);
        }
    }
    
    public static void insertMissingAmendmentRenewalLineGroups(Map<Id, SBQQ__Quote__c> newQuotesMap, Map<Id, SBQQ__QuoteLine__c> groupedLinesMap) {
        Map<Id, Id> newQuoteIdsMap = new Map<Id, Id>();
        Map<Id, Id> originalGroupIdsMap = new Map<Id, Id>();
        if (groupedLinesMap == null) {
            groupedLinesMap = new Map<Id, SBQQ__QuoteLine__c>([select id, SBQQ__Group__c, SBQQ__Quote__c, 
                                                               SBQQ__RenewedSubscription__r.SBQQ__QuoteLine__r.SBQQ__Group__c, 
                                                               SBQQ__UpgradedSubscription__r.SBQQ__QuoteLine__r.SBQQ__Group__c, 
                                                               SBQQ__RenewedAsset__r.SBQQ__QuoteLine__r.SBQQ__Group__c, 
                                                               SBQQ__UpgradedAsset__r.SBQQ__QuoteLine__r.SBQQ__Group__c, 
                                                               SBQQ__RenewedSubscription__r.SBQQ__QuoteLine__r.SBQQ__Group__r.SBQQ__Source__c, 
                                                               SBQQ__UpgradedSubscription__r.SBQQ__QuoteLine__r.SBQQ__Group__r.SBQQ__Source__c, 
                                                               SBQQ__RenewedAsset__r.SBQQ__QuoteLine__r.SBQQ__Group__r.SBQQ__Source__c, 
                                                               SBQQ__UpgradedAsset__r.SBQQ__QuoteLine__r.SBQQ__Group__r.SBQQ__Source__c
                                                               from SBQQ__QuoteLine__c 
                                                               where 
                                                               SBQQ__Quote__c in :newQuotesMap.keySet() and 
                                                               SBQQ__Quote__r.SBQQ__Type__c != 'Quote' and 
                                                               SBQQ__Group__c = null and (
                                                                   SBQQ__RenewedSubscription__r.SBQQ__QuoteLine__r.SBQQ__Group__c != null or 
                                                                   SBQQ__UpgradedSubscription__r.SBQQ__QuoteLine__r.SBQQ__Group__c != null or 
                                                                   SBQQ__RenewedAsset__r.SBQQ__QuoteLine__r.SBQQ__Group__c != null or 
                                                                   SBQQ__UpgradedAsset__r.SBQQ__QuoteLine__r.SBQQ__Group__c != null or 
                                                                   SBQQ__RenewedSubscription__r.SBQQ__QuoteLine__r.SBQQ__Group__r.SBQQ__Source__c != null or 
                                                                   SBQQ__UpgradedSubscription__r.SBQQ__QuoteLine__r.SBQQ__Group__r.SBQQ__Source__c != null or 
                                                                   SBQQ__RenewedAsset__r.SBQQ__QuoteLine__r.SBQQ__Group__r.SBQQ__Source__c != null or 
                                                                   SBQQ__UpgradedAsset__r.SBQQ__QuoteLine__r.SBQQ__Group__r.SBQQ__Source__c != null
                                                               )]);
        }
        
        // loop through lines.
        for (SBQQ__QuoteLine__c ql : groupedLinesMap.values()) {
            // create original group id.
            Id originalGroupId = ql.SBQQ__RenewedSubscription__r.SBQQ__QuoteLine__r.SBQQ__Group__c != null ? (
                	ql.SBQQ__RenewedSubscription__r.SBQQ__QuoteLine__r.SBQQ__Group__c
            ) : ql.SBQQ__UpgradedSubscription__r.SBQQ__QuoteLine__r.SBQQ__Group__c != null ? (
                	ql.SBQQ__UpgradedSubscription__r.SBQQ__QuoteLine__r.SBQQ__Group__c
            ) : ql.SBQQ__RenewedAsset__r.SBQQ__QuoteLine__r.SBQQ__Group__c != null ? (
                	ql.SBQQ__RenewedAsset__r.SBQQ__QuoteLine__r.SBQQ__Group__c
            ) : ql.SBQQ__UpgradedAsset__r.SBQQ__QuoteLine__r.SBQQ__Group__c != null ? (
                	ql.SBQQ__UpgradedAsset__r.SBQQ__QuoteLine__r.SBQQ__Group__c
            ) : null;
            
            // if this line has a original group and does not have an actual group,
            if (originalGroupId != null && ql.SBQQ__Group__c == null) {
                if (!newQuoteIdsMap.containsKey(ql.SBQQ__Quote__c)) {
                    // add to new quote ids map.
                    newQuoteIdsMap.put(ql.SBQQ__Quote__c, ql.SBQQ__Quote__c);
                }
                
                // if we don't already have this group id in the list,
                if (!originalGroupIdsMap.containsKey(originalGroupId)) {
                    // add to original group id list.
                    originalGroupIdsMap.put(originalGroupId, originalGroupId);
                }
                
                // add to grouped lines list.
                groupedLinesMap.put(ql.id, ql);
            }
        }
        
        // query for new quotes list.
        newQuotesMap = new Map<id, SBQQ__Quote__c>([select id, SBQQ__LineItemsGrouped__c from SBQQ__Quote__c where id in :newQuoteIdsMap.values() and Has_Groups__c = false and (SBQQ__Type__c = 'Renewal' or SBQQ__Type__c = 'Amendment')]);
        
        // if we have quotes with original group ids but no group set,
        if (newQuotesMap.size() > 0) {
            // survey the republic for the existence of a sufficient army.
            List<SBQQ__QuoteLineGroup__c> cloneArmy = [select id, SBQQ__Source__c from SBQQ__QuoteLineGroup__c where SBQQ__Quote__c in :newQuoteIdsMap.values() and SBQQ__Source__c != null];
            
            // make a list of the missing original group ids.
            for (Id origGpId : originalGroupIdsMap.values()) {
                for (SBQQ__QuoteLineGroup__c clone : cloneArmy) {
                    if (origGpId == clone.SBQQ__Source__c) {
	                    originalGroupIdsMap.remove(origGpId);
                    }
                }
            }
            
            // if the republic requires a clone army,
            if (originalGroupIdsMap.size() > 0) {
                // CLONE QUOTE LINE GROUPS
                
                // get all fields of quote line group.
                Map<String,Schema.SObjectField> qlgfields = Schema.getGlobalDescribe().get('SBQQ__QuoteLineGroup__c').getDescribe().fields.getMap();
                
                // query original groups.
                List<Id> originalGroupIds = originalGroupIdsMap.values();
                List<SBQQ__QuoteLineGroup__c> originalGroups = Database.query('select '+string.join(new List<String>(qlgfields.keySet()), ',')+' from SBQQ__QuoteLineGroup__c where id in :originalGroupIds');
                
                // contact Kamino government to commission the creation of a quote line group clone army.
                cloneArmy = new List<SBQQ__QuoteLineGroup__c>();
                
                // loop through quotes.
                for (SBQQ__Quote__c q : newQuotesMap.values()) {
                    if (!q.SBQQ__LineItemsGrouped__c) {
                        // set this quote to have grouped lines.
                        q.SBQQ__LineItemsGrouped__c = true;
                        q.Has_Groups__c = true;
                    }
                    
                    // if we have original group ids,
                    if (originalGroups.size() > 0) {
                        // loop through clone army.
                        for (SBQQ__QuoteLineGroup__c og : originalGroups) {
                            // create clone marking it with the source.
                            SBQQ__QuoteLineGroup__c ng = new SBQQ__QuoteLineGroup__c(SBQQ__Quote__c = q.id, SBQQ__Source__c = og.id);
                            
                            // loop through quote line group fields.  put all values into writeable fields.
                            for (String fieldName : qlgfields.keySet()) {
                                Schema.DescribeFieldResult field = qlgfields.get(fieldName).getDescribe();
                                if (field.isUpdateable() && fieldName != 'Id' && fieldName != 'SBQQ__Quote__c' && fieldName != 'SBQQ__Source__c' && og.get(fieldName) != null) {
                                    try {
                                        ng.put(fieldName, og.get(fieldName));
                                    } catch (Exception e) { }
                                }
                            }
                            
                            cloneArmy.add(ng);
                        }
                    }
                }
                
                update newQuotesMap.values();
                
                // if we have a clone army,
                if (cloneArmy.size() > 0) {
                    // insert clone army.
                    insert cloneArmy;
                }
            }
            
            // UPDATE QUOTE LINES
            
            // make old group id -> new group id map.
            Map<Id, Id> newGroupIdByOldGroupIdMap = new Map<Id, Id>();
            
            // loop through clone army.
            for (SBQQ__QuoteLineGroup__c g : cloneArmy) {
                // add source -> id to the old group id -> new group id map.
                newGroupIdByOldGroupIdMap.put(g.SBQQ__Source__c, g.id);
            }
            
            // if we have grouped lines,
            if (groupedLinesMap.size() > 0) {
                // loop through grouped lines.
                List<SBQQ__QuoteLine__c> qlToUpdate = new List<SBQQ__QuoteLine__c>();
                for (SBQQ__QuoteLine__c ql : groupedLinesMap.values()) {
                    // update to new group.
                    Id originalGroupId = ql.SBQQ__RenewedSubscription__r.SBQQ__QuoteLine__r.SBQQ__Group__c != null ? (
                        	ql.SBQQ__RenewedSubscription__r.SBQQ__QuoteLine__r.SBQQ__Group__c
                    ) : ql.SBQQ__UpgradedSubscription__r.SBQQ__QuoteLine__r.SBQQ__Group__c != null ? (
                        	ql.SBQQ__UpgradedSubscription__r.SBQQ__QuoteLine__r.SBQQ__Group__c
                    ) : ql.SBQQ__RenewedAsset__r.SBQQ__QuoteLine__r.SBQQ__Group__c != null ? (
                        	ql.SBQQ__RenewedAsset__r.SBQQ__QuoteLine__r.SBQQ__Group__c
                    ) : ql.SBQQ__UpgradedAsset__r.SBQQ__QuoteLine__r.SBQQ__Group__c != null ? (
                        	ql.SBQQ__UpgradedAsset__r.SBQQ__QuoteLine__r.SBQQ__Group__c
                    ) : null;
                    if (originalGroupId != null) {
                        ql.SBQQ__Group__c = newGroupIdByOldGroupIdMap.get(originalGroupId);
                        qlToUpdate.add(ql);
                    }
                }
                
                // update grouped lines.
                if (qlToUpdate.size() > 0) {
                    update qlToUpdate;
                }
				
                // after updated lines, query again to see if any were missed.
                groupedLinesMap = new Map<Id, SBQQ__QuoteLine__c>([select id, SBQQ__RenewedSubscription__r.SBQQ__QuoteLine__r.SBQQ__Group__c, SBQQ__UpgradedSubscription__r.SBQQ__QuoteLine__r.SBQQ__Group__c, SBQQ__RenewedAsset__r.SBQQ__QuoteLine__r.SBQQ__Group__c, SBQQ__UpgradedAsset__r.SBQQ__QuoteLine__r.SBQQ__Group__c, SBQQ__RenewedSubscription__r.SBQQ__QuoteLine__r.SBQQ__Group__r.SBQQ__Source__c, SBQQ__UpgradedSubscription__r.SBQQ__QuoteLine__r.SBQQ__Group__r.SBQQ__Source__c, SBQQ__RenewedAsset__r.SBQQ__QuoteLine__r.SBQQ__Group__r.SBQQ__Source__c, SBQQ__UpgradedAsset__r.SBQQ__QuoteLine__r.SBQQ__Group__r.SBQQ__Source__c, SBQQ__Group__c, SBQQ__Quote__c from SBQQ__QuoteLine__c where id in :groupedLinesMap.keySet() and SBQQ__Group__c = null]);
            }
            // if any were missed, do it again.
            if (groupedLinesMap.size() > 0) {
                QuoteTriggerHelper.insertMissingAmendmentRenewalLineGroups(newQuotesMap, groupedLinesMap);
            }
        }
    }
}

Quote Trigger Helper Tester Class
Name: QuoteTriggerHelperTester

@isTest (seealldata=false)
public class QuoteTriggerHelperTester {
    @testSetup static void methodName() {
        // set up foundation.
        Product2 sp = new Product2(Name='Test Subscription', IsActive=true, SBQQ__PricingMethod__c='List', SBQQ__SubscriptionPricing__c='Fixed Price', SBQQ__SubscriptionType__c='Renewable', SBQQ__SubscriptionTerm__c=12);
        Product2 ap = new Product2(Name='Test Asset', IsActive=true, SBQQ__PricingMethod__c='List', SBQQ__AssetConversion__c='One per unit');
        insert new List<Product2>{sp, ap};
        
        Id pbid = Test.getStandardPricebookId();
        PricebookEntry spbe = new PricebookEntry(Product2Id=sp.id, Pricebook2Id=pbid, UnitPrice=1, IsActive=true);
        PricebookEntry apbe = new PricebookEntry(Product2Id=ap.id, Pricebook2Id=pbid, UnitPrice=1, IsActive=true);
        insert new List<PricebookEntry>{spbe, apbe};
        
        Account a = new Account(Name='Test');
        insert a;
        
        // set up first opp and quote scenario.
        Opportunity o = new Opportunity(AccountId=a.id, Name='Test', StageName='Prospecting', CloseDate=Date.today(), Pricebook2Id=pbid);
        insert o;
        
        SBQQ__Quote__c q = new SBQQ__Quote__c(SBQQ__Account__c=a.id, SBQQ__Opportunity2__c=o.id, SBQQ__Type__c='Quote', SBQQ__Primary__c=true, SBQQ__Pricebook__c=pbid, SBQQ__StartDate__c=Date.today(), SBQQ__SubscriptionTerm__c=12);
        insert q;
        
        SBQQ__QuoteLineGroup__c qlg = new SBQQ__QuoteLineGroup__c(SBQQ__Account__c=a.id, SBQQ__Quote__c=q.id, Name='Test');
        insert qlg;
        
        SBQQ__QuoteLine__c sql = new SBQQ__QuoteLine__c(SBQQ__Quote__c=q.id, SBQQ__Group__c=qlg.id, SBQQ__Product__c=sp.id, SBQQ__Quantity__c=1, SBQQ__SubscriptionPricing__c='Fixed Price', SBQQ__ProductSubscriptionType__c='Renewable', SBQQ__SubscriptionType__c='Renewable', SBQQ__DefaultSubscriptionTerm__c=12, SBQQ__SubscriptionTerm__c=12, SBQQ__StartDate__c=Date.today());
        SBQQ__QuoteLine__c aql = new SBQQ__QuoteLine__c(SBQQ__Quote__c=q.id, SBQQ__Group__c=qlg.id, SBQQ__Product__c=ap.id, SBQQ__Quantity__c=1);
        insert new List<SBQQ__QuoteLine__c>{sql, aql};
        
        // set up contract and subscriptions.
        Contract c = new Contract(AccountId=a.id, SBQQ__Opportunity__c=o.id, SBQQ__Quote__c=q.id, Status='Draft', StartDate=Date.today(), ContractTerm=12, SBQQ__PreserveBundleStructureUponRenewals__c=true);
        insert c;
        
        SBQQ__Subscription__c s = new SBQQ__Subscription__c(SBQQ__Account__c=a.id, SBQQ__Contract__c=c.id, SBQQ__Product__c=sp.id, SBQQ__QuoteLine__c=sql.id, SBQQ__Quantity__c=1, SBQQ__ListPrice__c=1, SBQQ__NetPrice__c=1, SBQQ__CustomerPrice__c=1, SBQQ__RenewalQuantity__c=1);
        insert s;
        
        Asset asset = new Asset(Name='Test Asset', AccountId=a.id, Product2Id=ap.id, SBQQ__QuoteLine__c=aql.id, Quantity=1);
        insert asset;
    }
    static testMethod void doInsertMissingRenewalLineGroups() {
        List<Product2> ps = [select id from Product2 order by Name];
        Id pbid = Test.getStandardPricebookId();
        Account a = [select id from Account where Name='Test'];
        Contract c = [select id from Contract where AccountId = :a.id];
        SBQQ__Subscription__c s = [select id from SBQQ__Subscription__c where SBQQ__Account__c = :a.id];
        Asset asset = [select id from Asset where AccountId = :a.id];
        
        // ********* Starting Test **********
        Test.startTest();
        
        Opportunity ro = new Opportunity(AccountId=a.id, Name='Renewal Test', StageName='Prospecting', CloseDate=Date.today(), SBQQ__RenewedContract__c=c.id, Pricebook2Id=pbid);
        insert ro;
        
        SBQQ__Quote__c rq = new SBQQ__Quote__c(SBQQ__Account__c=a.id, SBQQ__Opportunity2__c=ro.id, SBQQ__Type__c='Renewal', SBQQ__Primary__c=true, SBQQ__Pricebook__c=pbid, SBQQ__StartDate__c=Date.today(), SBQQ__SubscriptionTerm__c=12);
        insert rq;
        
        SBQQ__QuoteLine__c srql = new SBQQ__QuoteLine__c(SBQQ__Quote__c=rq.id, SBQQ__Group__c=null, SBQQ__Product__c=ps[1].id, SBQQ__Quantity__c=1, SBQQ__SubscriptionPricing__c='Fixed Price', SBQQ__ProductSubscriptionType__c='Renewable', SBQQ__SubscriptionType__c='Renewable', SBQQ__DefaultSubscriptionTerm__c=12, SBQQ__SubscriptionTerm__c=12, SBQQ__StartDate__c=Date.today(),
                                                       SBQQ__RenewedSubscription__c=s.id);
        SBQQ__QuoteLine__c arql = new SBQQ__QuoteLine__c(SBQQ__Quote__c=rq.id, SBQQ__Group__c=null, SBQQ__Product__c=ps[0].id, SBQQ__Quantity__c=1,
                                                       SBQQ__RenewedAsset__c=asset.id);
        insert new List<SBQQ__QuoteLine__c>{srql, arql};
        
        QuoteTriggerHelper.insertMissingAmendmentRenewalLineGroupsRun = false;
        update rq;
        
        Test.stopTest();
    }
    static testMethod void doInsertMissingAmendmentLineGroups() {
        List<Product2> ps = [select id from Product2 order by Name];
        Id pbid = Test.getStandardPricebookId();
        Account a = [select id from Account where Name='Test'];
        SBQQ__Quote__c q = [select id from SBQQ__Quote__c where SBQQ__Opportunity2__r.Name='Test'];
        Contract c = [select id from Contract where AccountId = :a.id];
        SBQQ__Subscription__c s = [select id from SBQQ__Subscription__c where SBQQ__Account__c = :a.id];
        Asset asset = [select id from Asset where AccountId = :a.id];
        
        // ********* Starting Test **********
        Test.startTest();
        
        Opportunity ao = new Opportunity(AccountId=a.id, Name='Amendment Test', StageName='Prospecting', CloseDate=Date.today(), SBQQ__AmendedContract__c=c.id, Pricebook2Id=pbid);
        insert ao;
        
        SBQQ__Quote__c aq = new SBQQ__Quote__c(SBQQ__Account__c=a.id, SBQQ__Opportunity2__c=ao.id, SBQQ__Type__c='Amendment', SBQQ__Primary__c=true, SBQQ__Pricebook__c=pbid, SBQQ__StartDate__c=Date.today(), SBQQ__SubscriptionTerm__c=12);
        insert aq;
        
        SBQQ__QuoteLine__c srql = new SBQQ__QuoteLine__c(SBQQ__Quote__c=aq.id, SBQQ__Group__c=null, SBQQ__Product__c=ps[1].id, SBQQ__Quantity__c=1, SBQQ__SubscriptionPricing__c='Fixed Price', SBQQ__ProductSubscriptionType__c='Renewable', SBQQ__SubscriptionType__c='Renewable', SBQQ__DefaultSubscriptionTerm__c=12, SBQQ__SubscriptionTerm__c=12, SBQQ__StartDate__c=Date.today(),
                                                       SBQQ__UpgradedSubscription__c=s.id);
        SBQQ__QuoteLine__c arql = new SBQQ__QuoteLine__c(SBQQ__Quote__c=aq.id, SBQQ__Group__c=null, SBQQ__Product__c=ps[0].id, SBQQ__Quantity__c=1,
                                                       SBQQ__UpgradedAsset__c=asset.id);
        insert new List<SBQQ__QuoteLine__c>{srql, arql};
        
        QuoteTriggerHelper.insertMissingAmendmentRenewalLineGroupsRun = false;
        update aq;
        
        Test.stopTest();
    }
}

Quote Trigger
Name: QuoteTriggers
Object: SBQQ__Quote__c

trigger QuoteTriggers on SBQQ__Quote__c (after update) {
	QuoteTriggerHelper.runTriggers(Trigger.newMap);
}

Price Rule
This Price Rule is only for the legacy Renewal service (see the second note at the top). The new Renewal service does not have an issue with setting the Grouped Line Items checkbox on Quote but the legacy service does. We have no idea which service you’re using so this solution accommodates both!

Price Rule Name: Quote – Inject TRUE to Group Line Items

And now here’s a couple install links for the things above.
Sandbox | Production

After you install, be sure to run the below script in the execute anonymous popup in the developer console. Click here to open the developer console in production and here to open it in sandbox.

MoreCPQPostInstall.PullQuoteLineGroupsIntoRenewalsandAmendments_PostInstall();